SED(1)

NAME
sed - stream editor

SYNOPSIS
sed [-aEnru] command [file ...]
sed [-aEnru] [-e command] [-f command_file] [file ...]

DESCRIPTION
The sed utility reads the specified files, or the standard input if no files are specified, modifying the input as specified by a list of commands. The input is then written to the standard output.

A single command may be specified as the first argument to sed. Multiple commands may be specified separated by newlines or semicolons, or by using the -e or -f options. All commands are applied to the input in the order they are specified regardless of their origin.

The options are as follows:

-a  The files listed as parameters for the w function or flag are created (or truncated) before any processing begins, by default. The -a option causes sed to delay opening each file until a command containing the related w function or flag is applied to a line of input.

-E  Interpret regular expressions using POSIX extended regular expression syntax. The default behaviour is to use POSIX basic regular expression syntax.

-e command
    Append the editing commands specified by the command argument to the list of commands.

-f command_file
    Append the editing commands found in the file command_file to the list of commands. The editing commands should each be listed on a separate line.

-r  An alias for -E, for compatibility with GNU sed.

-n  By default, each line of input is echoed to the standard output after all of the commands have been applied to it. The -n option suppresses this behavior.

-u  Force output to be line buffered, printing each line as it becomes available. By default, output is line buffered when standard output is a terminal and block buffered otherwise. See setbuf(3) for a more detailed explanation.

The form of a sed command is as follows:

    [address[,address]]function[arguments]

Whitespace may be inserted before the first address and the function portions of the command.

Normally, sed cyclically copies a line of input, not including its terminating newline character, into a pattern space, (unless there is something left after a D function), applies all of the commands with addresses that select that pattern space, copies the pattern space to the standard output, appending a newline, and deletes the pattern space.

Some of the functions use a hold space to save all or part of the pattern space for subsequent retrieval.

SED ADDRESSES
An address is not required, but if specified must be a number (that counts input lines cumulatively across input files), a dollar character (‘$’) that addresses the last line of input, or a context address (which consists of a regular expression preceded and followed by a delimiter).

A command line with no addresses selects every pattern space.

A command line with one address selects all of the pattern spaces that match the address.

A command line with two addresses selects the inclusive range from the first pattern space that matches the first address through the next pattern space that matches the second. (If the second address is a number less than or equal to the line number first selected, only that line is selected.) Starting at the first line following the selected range, sed starts looking again for the first address.

Editing commands can be applied to non-selected pattern spaces by use of the exclamation character (‘’)! function.

SED REGULAR EXPRESSIONS
By default, sed regular expressions are basic regular expressions (BREs). Extended regular expressions are supported using the -E and -r options. See re_format(7) for more information on regular expressions. In addition, sed has the following two additions to BREs:

1.  In a context address, any character other than a backslash (‘\’) or newline character may be used to delimit the regular expression. The opening delimiter should be preceded by a backslash unless it is a slash. Putting a backslash character before the delimiting character causes the character to be treated literally. For example, in the context address \xabc\xdefx, the RE delimiter is an ‘x’ and the second ‘x’ stands for itself, so that the regular expression is “abcxdef”.

2.  The escape sequence \n matches a newline character embedded in the pattern space. You can't, however, use a literal newline character in an address or in the substitute command.

One special feature of sed regular expressions is that they can default to the last regular expression used. If a regular expression is empty, i.e., just the delimiter characters are specified, the last regular expression encountered is used instead. The last regular expression is defined as the last regular expression used as part of an address or substitute command, and at run-time, not compile-time. For example, the command “/abc/s//XXX/” will substitute “XXX” for the pattern “abc”.

SED FUNCTIONS
In the following list of commands, the maximum number of permissible addresses for each command is indicated by [0addr], [1addr], or [2addr], representing zero, one, or two addresses.

The argument text consists of one or more lines. To embed a newline in the text, precede it with a backslash. Other backslashes in text are deleted and the following character taken literally.

The r and w functions, as well as the w flag to the s function, take an optional file parameter, which should be separated from the function or flag by whitespace. Files are created (or their contents truncated) before any input processing begins.

The b, r, s, t, w, y, and: functions all accept additional arguments. The synopses below indicate which arguments have to be separated from the function letters by whitespace characters.

Functions can be combined to form a function list, a list of sed functions each followed by a newline, as follows:

    { function
      function
      ...
      function
    }

The braces can be preceded and followed by whitespace. The functions can be preceded by whitespace as well.

Functions and function lists may be preceded by an exclamation mark, in which case they are applied only to lines that are not selected by the addresses.

[2addr] function-list
    Execute function-list only when the pattern space is selected.

[1 addr] a\
    text

    Write text to standard output immediately before each attempt to read a line of input, whether by executing the N function or by beginning a new cycle.

[2addr]b [label]
    Branch to the: function with the specified label. If the label is not specified, branch to the end of the script.

[2addr] c\
    text

    Delete the pattern space. With 0 or 1 address or at the end of a 2-address range, text is written to the standard output.

[2addr]d
    Delete the pattern space and start the next cycle.

[2addr]D
    Delete the initial segment of the pattern space through the first newline character and start the next cycle.

[2addr]g
    Replace the contents of the pattern space with the contents of the hold space.

[2addr]G
    Append a newline character followed by the contents of the hold space to the pattern space.

[2addr]h
    Replace the contents of the hold space with the contents of the pattern space.

[2addr]H
    Append a newline character followed by the contents of the pattern space to the hold space.

[1addr] i\
    text

    Write text to the standard output.

[2addr]l
    (The letter ell.) Write the pattern space to the standard output in a visually unambiguous form. This form is as follows:

    backslash
        \\
    alert
        \a
    backspace
        \b
    form-feed
        \f
    carriage-return
        \r
    tab \t
    vertical tab
        \v

    Non-printable characters are written as three-digit octal numbers (with a preceding backslash) for each byte in the character (most significant byte first). Long lines are folded, with the point of folding indicated by displaying a backslash followed by a newline. The end of each line is marked with a ‘$’.

[2addr]n
    Write the pattern space to the standard output if the default output has not been suppressed, and replace the pattern space with the next line of input.

[2addr]N
    Append the next line of input to the pattern space, using an embedded newline character to separate the appended material from the original contents. Note that the current line number changes.

[2addr]p
    Write the pattern space to standard output.

[2addr]P
    Write the pattern space, up to the first newline character, to the standard output.

[1addr]q
    Branch to the end of the script and quit without starting a new cycle.

[1addr]r file
    Copy the contents of file to the standard output immediately before the next attempt to read a line of input. If file cannot be read for any reason, it is silently ignored and no error condition is set.

[2addr]s/RE/replacement/flags
    Substitute the replacement string for the first instance of the regular expression RE in the pattern space. Any character other than backslash or newline can be used instead of a slash to delimit the regular expression and the replacement. Within the regular expression and the replacement, the regular expression delimiter itself can be used as a literal character if it is preceded by a backslash.

    An ampersand (‘&’) appearing in the replacement is replaced by the string matching the regular expression. The special meaning of ‘&’ in this context can be suppressed by preceding it by a backslash. The string ‘\#’, where ‘#’ is a digit, is replaced by the text matched by the corresponding backreference expression (see re_format(7)).

    A line can be split by substituting a newline character into it. To specify a newline character in the replacement string, precede it with a backslash.

    The value of flags in the substitute function is zero or more of the following:

    0 ... 9
        Make the substitution only for the N'th occurrence of the regular expression in the pattern space.

    g   Make the substitution for all non-overlapping matches of the regular expression, not just the first one.

    p   Write the pattern space to standard output if a replacement was made. If the replacement string is identical to that which it replaces, it is still considered to have been a replacement.

    w file
        Append the pattern space to file if a replacement was made. If the replacement string is identical to that which it replaces, it is still considered to have been a replacement.

[2addr]t [label]
    Branch to the: function bearing the label if any substitutions have been made since the most recent reading of an input line or execution of a t function. If no label is specified, branch to the end of the script.

[2addr]w file
    Append the pattern space to the file.

[2addr]x
    Swap the contents of the pattern and hold spaces.

[2addr]y/string1/string2/
    Replace all occurrences of characters in string1 in the pattern space with the corresponding characters from string2. Any character other than a backslash or newline can be used instead of a slash to delimit the strings. Within string1 and string2, a backslash followed by any character other than a newline is that literal character, and a backslash followed by an ‘n’ is replaced by a newline character.

[0addr]:label
    This function does nothing; it bears a label to which the b and t commands may branch.

[1addr]=
    Write the line number to the standard output followed by a newline character.

[0addr]
    Empty lines are ignored.

[0addr]#
    The ‘#’ and the remainder of the line are ignored (treated as a comment), with the single exception that if the first two characters in the file are ‘#n’, the default output is suppressed. This is the same as specifying the -n option on the command line.

EXIT STATUS

EXAMPLES
The following simulates the cat(1) -s command, squeezing excess empty lines from standard input:

    $ sed -n '
    # Write non-empty lines.
    /./ {
        p
        d
        }
    # Write a single empty line, then look for more empty lines.
    /^$/    p
    # Get the next line, discard the held <newline> (empty line),
    # and look for more empty lines.
    :Empty
    /^$/    {
        N
        s/.//
        b Empty
        }
    # Write the non-empty line before going back to search
    # for the first in a set of empty lines.
        p
    '

SEE ALSO
awk(1), ed(1), grep(1), re_format(7)

STANDARDS
The sed utility is compliant with the p1003.1-2008 specification.

The flags [-aEru] are extensions to that specification.

The use of newlines to separate multiple commands on the command line is non-portable; the use of newlines to separate multiple commands within a command file (-f command_file) is portable.

HISTORY
A sed command appeared in AT&T UNIX.

CAVEATS
The use of semicolons to separate multiple commands is not permitted for the following commands: a, b, c, i, r, t, w,:, and #.